#include "colors.inc"

#declare MyLoc = <0, 0, -1>;

camera {
  location MyLoc
  look_at <0, 0, 0>
}

sky_sphere {
  pigment {
    gradient y
    color_map { [0.0 color blue 0.6] [1.0 color rgb 1] }
  }
}

light_source { MyLoc White }

plane {
  y, -1.5
  texture {
    pigment {checker color White color Blue scale 0.5}
    finish {reflection 0.2}
  }
}

// ----------------------------------------

#declare Spir1 = pigment {
  spiral1 -5
  color_map {
    [0.00 color rgbt <3, 3  , 3  , 0>]
    [0.25 color rgbt <0, 1.5, 0  , 0>]
    [0.50 color rgbt <0, 0  , 0  , 1>]
    [0.75 color rgbt <0, 0  , 1.5, 0>]
    [1.00 color rgbt <3, 3  , 3  , 0>]
  }
  rotate z * clock * (360 / 5)
}

#declare Spir2 = pigment {
  spiral1 5
  color_map {
    [0.00 color rgbt <3,   3,   3,   0>]
    [0.25 color rgbt <0,   1.5, 0,   0>]
    [0.50 color rgbt <0,   0,   0,   1>]
    [0.75 color rgbt <1.5, 0,   0,   0>]
    [1.00 color rgbt <3,   3,   3,   0>]
  }
  rotate z * -clock * (360 / 5)
}

cylinder {
  z* -1e10, z* +1e10, 1
  inverse
  hollow
  texture {
    pigment {
      average pigment_map {
        [1 Spir1]
        [1 Spir2]
      }
      scale <3, 3, 6>
    }
    finish {
      reflection .1
    }
  }
}