# Copyright 2003-2004 Kevin Reid.
# This source code and related files are distributed under the MIT License, as described in the document named "License.txt" which should be provided with this source distribution.

pragma.enable("explicit-result-guard")
pragma.disable("no-dot-call")
pragma.disable("easy-return")

pragma.enable("importer")
pragma.enable("exporter")
pragma.enable("pattern-default")
pragma.enable("map-tail")

def <den>                    := <import:org.cubik.den.*>
def lazy                     := <den:util.lazy>
def makeThing                := lazy(fn{ <den:makeThing> })

def makeKey {
  to __optUncall() :any { return [<import>, "get", [meta.context().getFQNPrefix().split("$")[0]]] }

  to run([
    => self := (def key; key), 
    "super" => optSuper := null,
    => var sealer
  ] | superArgs) :any {
    bind key extends if (optSuper != null) { optSuper } else { makeThing([=> self] | superArgs | ["name" => "key", "description" => "A key."]) } {
      to __optUncall() :any {
        [makeKey, "run", [[=> self, => super, => sealer]]]
      }

      to __conformTo(guard) :any {
        if (guard.__respondsTo("isDenDetailGuard", 0) && guard.isDenDetailGuard()) {
          return super.__conformTo(guard)
        } else {
          self
        }
      }
    
      to getSealer() :any { sealer }
      to setSealer(new) :any { sealer := new }
      
      to exterior_getOptUnlocker() :any {
        sealer
      }
    
    } #end bind key
  } #end run(self, params)
}

? def makeKey := <import:org.cubik.den.makeKey>
# value: <makeKey>

?# fixme: more updoc